Подскажите пожалуйста как результат СКД в таблицу значений загрузить? Программа ЗУП, отчет правлю типовой по исполнительным листам...

ручами надо все делать

+(1) в смысле, что конструктором не обойтись тут.
Надо всю компоновку кодом строить.

т.е. надо сделать отчет внешним и скопировать в него весь код из общих модулей, а потом править его?

в книге Хрусталёвой есть пример как делать

пример. ....Программно формируем отчет и дальше через МВТ....
   
ДанныеРасшифровки= Новый ДанныеРасшифровкиКомпоновкиДанных;
КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
МакетКомпоновки = КомпоновщикМакета.Выполнить(ЭтотОбъект.СхемаКомпоновкиДанных,КомпоновщикНастроек.Настройки,ДанныеРасшифровки);
   
МВТ = Новый МенеджерВременныхТаблиц;
Запрос = Новый Запрос;
Запрос.МенеджерВременныхТаблиц = МВТ;
Запрос.Текст = МакетКомпоновки.НаборыДанных[0].Запрос;
Для Каждого Параметр из МакетКомпоновки.ЗначенияПараметров Цикл
   Запрос.УстановитьПараметр(Параметр.Имя, Параметр.Значение);        
КонецЦикла;
ТЗ = Запрос.Выполнить().Выгрузить();

(5) Тут будет только запрос. А как-же вычисляемые поля, ресурсы, отборы?

СКД = Новый СхемаКомпоновкиДанных;
   
//Опишем источники как они есть в отчете
ИсточникДанных = СКД.ИсточникиДанных.Добавить();
ИсточникДанных.Имя = "ИсточникДанных1";
ИсточникДанных.ТипИсточникаДанных = "Local";

НаборДанных = СКД.НаборыДанных.Добавить(Тип("НаборДанныхЗапросСхемыКомпоновкиДанных"));
НаборДанных.Имя = "НаборДанных1";
НаборДанных.ИсточникДанных = "ИсточникДанных1";
НаборДанных.Запрос = ТекстЗапроса;
   
Компоновщик = Новый КомпоновщикНастроекКомпоновкиДанных;
Компоновщик.Инициализировать(Новый ИсточникДоступныхНастроекКомпоновкиДанных(СКД));
Компоновщик.ЗагрузитьНастройки(КомпоновщикНастроек.Настройки); //Настрой получим из настоящего отчета
Компоновщик.Восстановить();
       
КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
МакетКомпоновки = КомпоновщикМакета.Выполнить(СКД, Компоновщик.Настройки,,, Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений"));

ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки);

ТаблицаЗначений = Новый ТаблицаЗначений;
   
ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;
ПроцессорВывода.УстановитьОбъект(ТаблицаЗначений);
   
ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);

http://1cskd.ru/2010/07/vyvod-otcheta-v-kollekciyu-znachenij/

или так?)
ТаблицаЗначений = Новый ТаблицаЗначений;
ТиповыеОтчеты.СформироватьТиповойОтчет(ЭтотОбъект, ТаблицаЗначений, ДанныеРасшифровки, Ложь);

(6) я думал она знает как программно доводить отчета до экрана :)

(10) тебе сказали, что твой вариант не учитывает настройки СКД. Экран тут не при чем.